ASP XMLHTTP

admin

2013年11月28日 11:39 本文热度 5154

'********************************************************************************
'名称：远程抓取函数
'作用：利用XMLHTTP远程抓取数据
'参数： sMethod --- 发送方式
' sUrl ------ 目标地址
' iMode ----- 返回内容类型：0为二进制，1为文本，2为cookie，3为文件头信息
' sBase ----- 设定编码
' sReferer -- 设定来源
' sCookie --- 设定cookie
' sLanguage - 设定语言
' sData ----- 设定要发送的参数
' sContent -- 设定接收数据类型
' sAgent ---- 设定浏览器
' sEncoding - 设定gzip压缩
' sAccept --- 设定文档类型
'********************************************************************************
Public Function SenFe_StealData(sMethod, sUrl, iMode, sBase, sReferer, sCookie, sLanguage, sData, sContent, sAgent, sEncoding, sAccept)
Dim oXmlHttp : Set oXmlHttp = Server.CreateObject("Msxml2.ServerXMLHTTP")
With oXmlHttp
If sMethod="" Then sMethod = "GET"
.Open sMethod, sUrl, False
'设定页面来源
If sReferer<>"" Then
.SetRequestHeader "Referer", sReferer
Else
.SetRequestHeader "Referer", Split(sUrl, "/")(2)
End If
If sCookie<>"" Then .SetRequestHeader "Cookie", sCookie '设定Cookie
If sLanguage<>"" Then .SetRequestHeader "Accept-Language", sLanguage '设定语言
If sData<>"" Then .SetRequestHeader "Content-Length", Len(sData) '设定数据长度
If sContent<>"" Then .SetRequestHeader "Content-Type", sContent '设定接受数据类型
If sAgent<>"" Then .SetRequestHeader "User-Agent", sAgent '设定浏览器
If sEncoding<>"" Then .SetRequestHeader "Accept-Encoding", sEncoding '设定gzip压缩
If sAccept<>"" Then .SetRequestHeader "Accept", sAccept '文档类型
.Send sData
'While .ReadyState <> 4
' .WaitForResponse 1000
'Wend
If .ReadyState<>4 Or .Status<>200 Then
SenFe_StealData = "无法取到数据！"
Exit Function
End If
Select Case iMode
Case 0 SenFe_StealData = .ResponseBody
Case 1
If sBase<>"" Then
SenFe_StealData = BytesToBstr(.ResponseBody, sBase)
Else
SenFe_StealData = .ResponseText
End If
Case 2 SenFe_StealData = .getResponseHeader("Set-Cookie")
Case Else SenFe_StealData = .getAllResponseHeaders()
End Select
End With
End Function
'********************************************************************************
'作用：编码转换
'参数： sBody - 要转换的内容
' sCset - 编码
'********************************************************************************
Function BytesToBstr(sBody, sCset)
With oAdos
.Type = 1
.Mode = 3
.Open
.Write sBody
.Position = 0
.Type = 2
.Charset = sCset
BytesToBstr = .ReadText
.Close
End With
End Function

该文章在 2013/11/28 11:39:13 编辑过

正在查询...

点晴ERP是一款针对中小制造业的专业生产管理软件系统,系统成熟度和易用性得到了国内大量中小企业的青睐。

点晴PMS码头管理系统主要针对港口码头集装箱与散货日常运作、调度、堆场、车队、财务费用、相关报表等业务管理，结合码头的业务特点，围绕调度、堆场作业而开发的。集技术的先进性、管理的有效性于一体，是物流码头及其他港口类企业的高效ERP管理信息系统。

点晴WMS仓储管理系统提供了货物产品管理,销售管理,采购管理,仓储管理,仓库管理,保质期管理,货位管理,库位管理,生产管理,WMS管理系统,标签打印,条形码,二维码管理,批号管理软件。

点晴免费OA是一款软件和通用服务都免费，不限功能、不限时间、不限用户的免费OA协同办公管理系统。